{
  lib,
  rustPlatform,
  fetchFromGitHub,
  pkg-config,
  cmake,
  fontconfig,
  libxkbcommon,
  wayland,
  vulkan-loader,
  libxcb,
}:

rustPlatform.buildRustPackage rec {
  pname = "task-warrior-gpui";
  version = "0.3.0";

  src = fetchFromGitHub {
    owner = "0xErwin1";
    repo = "taskwarrior-gpui";
    rev = "v${version}";
    hash = "sha256-6nndsC5Q+4zmWFESpjas0c6BRb8medtLXoKzrPzpUus=";
  };

  cargoHash = "sha256-VPKLkLmMbzcILT8w1DDbvwOpeOraz2vSRiztWfR49nc=";

  nativeBuildInputs = [
    pkg-config
    cmake
    rustPlatform.bindgenHook
  ];

  buildInputs = [
    fontconfig
    libxkbcommon
    wayland
    libxcb
  ];

  postFixup = ''
    patchelf $out/bin/task-warrior-gpui --add-rpath ${
      lib.makeLibraryPath [
        wayland
        vulkan-loader
      ]
    }
  '';

  meta = {
    description = "A desktop GUI for TaskWarrior built with GPUI";
    homepage = "https://github.com/0xErwin1/taskwarrior-gpui";
    license = with lib.licenses; [
      mit
      asl20
    ];
    mainProgram = "task-warrior-gpui";
    platforms = lib.platforms.linux;
  };
}